The CUE Central Registry provides a well-known location for well-known schemas, including those for YAML pipeline files used by Azure pipelines. This guide shows you how to get started defining your Azure pipelines in CUE using a curated module from the schema library.

The latest pre-release of the cue command is required – please upgrade to this version if it’s not already installed:

$ cue version
cue version v0.13.0-alpha.3
...

Login to the Central Registry

$ cue login # only during beta

The Central Registry requires authentication while it’s in beta testing, so you need to login before you can use its schemas.

Initialise your local CUE module

CUE that uses schemas and modules from the Central Registry needs to exist within its own CUE module.

$ cue mod init cue.example

You can choose any module name you like - it’s easy to change it later. It makes sense for your CUE module to exist at the root of a git repository that’s supported by Azure Pipelines, but the commands in this guide will work in any setup.

Create a pipeline

Declare a Azure pipeline in CUE. This one is based on an example from the Azure Pipelines documentation:

// filepath: pipeline.cue

package cicd

import "cue.dev/x/azurepipelines"

pipelines: example: azurepipelines.#Pipeline & {
	trigger: ["main"]
	pool: vmImage: "ubuntu-latest"
	stages: [{
		stage:       "Build"
		displayName: "Build Stage"
		jobs: [{
			job:         "BuildJob"
			displayName: "Build Job"
			steps: [{
				script: """
					echo "Restoring project dependencies..."
					"""
				displayName: "Restore dependencies"
			}, {
				script: """
					echo "Running unit tests..."
					"""
				displayName: "Run unit tests"
			}]
		}]
	}]
}

In later guides we’ll add more entries to the pipelines struct.

The import at the top references the appropriate curated module for the pipeline. Its path is currently temporary, but only while its proper location is being decided. The temporary path isn’t a problem because one important property of the Central Registry is that, once a schema is published, it will always be available at that location. When the curated module’s location is finalised and versions are published under the new path, you can use the cue refactor imports command to update your CUE easily, so it reflects the new location.

Tidy your local CUE module

$ cue mod tidy

Tidying a module is an important part of using curated modules from the Central Registry. Always use cue mod tidy when you use a curated module for the first time.

Validate your pipeline

$ cue vet -c

Because cue vet doesn’t display any errors, you know that the curated schema has validated your pipeline.

Export your pipeline as YAML

$ cue export --outfile pipeline.yml -e pipelines.example

If you chose to export the pipelines.example shown above, your validated YAML pipeline will look like this:

# filepath: pipeline.yml

trigger:
  - main
pool:
  vmImage: ubuntu-latest
stages:
  - stage: Build
    displayName: Build Stage
    jobs:
      - job: BuildJob
        displayName: Build Job
        steps:
          - script: echo "Restoring project dependencies..."
            displayName: Restore dependencies
          - script: echo "Running unit tests..."
            displayName: Run unit tests

Run your pipeline

The cue.mod directory needs to be stored in your git repository, along with your pipeline.cue and pipeline.yml files. After recording them in a commit you can push your branch to your git remote and trigger the pipeline. Whenever you update your CUE pipeline, re-run the cue export command shown above, and then use git to record any changes to these files and directories.