The CUE Central Registry provides a well-known location for well-known schemas, including those for YAML pipeline files used by GitLab CI/CD. This guide shows you how to get started defining your GitLab CI/CD pipelines in CUE using a curated module from the schema library.

The latest pre-release of the cue command is required – please upgrade to this version if it’s not already installed:

$ cue version
cue version v0.13.0-alpha.3
...

Login to the Central Registry

$ cue login # only during beta

The Central Registry requires authentication while it’s in beta testing, so you need to login before you can use its schemas.

Initialise your local CUE module

CUE that uses schemas and modules from the Central Registry needs to exist within its own CUE module.

$ cue mod init cue.example

You can choose any module name you like - it’s easy to change it later. It makes sense for your CUE module to exist at the root of a git repository that’s hosted on GitLab, but the commands in this guide will work in any setup.

Create a pipeline

Declare a GitLab pipeline in CUE. This one is based on an example from GitLab’s documentation:

// filepath: pipeline.cue

package cicd

import "test.cue.works/x1/gitlab/gitlabci"

pipelines: example: gitlabci.#Pipeline & {
	default: image: "ruby:3.2"
	workflow: rules: [{if: "$CI_COMMIT_BRANCH"}]
	"deploy-pages": {
		stage: "deploy"
		script: [
			"gem install bundler",
			"bundle install",
			"bundle exec jekyll build -d public",
		]
		pages: true
		rules: [{if: "$CI_COMMIT_BRANCH == \"main\""}]
		environment: "production"
	}
	test: {
		stage: "test"
		script: [
			"gem install bundler",
			"bundle install",
			"bundle exec jekyll build -d test",
		]
		artifacts: paths: ["test"]
		rules: [{if: "$CI_COMMIT_BRANCH != \"main\""}]
	}
}

In later guides we’ll add more entries to the pipelines struct.

The import at the top references the appropriate curated module for the pipeline. Its path is currently temporary, but only while its proper location is being decided. The temporary path isn’t a problem because one important property of the Central Registry is that, once a schema is published, it will always be available at that location. When the curated module’s location is finalised and versions are published under the new path, you can use the cue refactor imports command to update your CUE easily, so it reflects the new location.

Tidy your local CUE module

$ cue mod tidy

Tidying a module is an important part of using curated modules from the Central Registry. Always use cue mod tidy when you use a curated module for the first time.

Validate your pipeline

$ cue vet -c

Because cue vet doesn’t display any errors, you know that the curated schema has validated your pipeline.

Export your pipeline as YAML

$ cue export --outfile .gitlab-ci.yml -e pipelines.example

If you chose to export the pipelines.example shown above, your validated YAML pipeline will look like this:

# filepath: .gitlab-ci.yml

default:
  image: ruby:3.2
workflow:
  rules:
    - if: $CI_COMMIT_BRANCH
deploy-pages:
  rules:
    - if: $CI_COMMIT_BRANCH == "main"
  script:
    - gem install bundler
    - bundle install
    - bundle exec jekyll build -d public
  stage: deploy
  environment: production
  pages: true
test:
  rules:
    - if: $CI_COMMIT_BRANCH != "main"
  script:
    - gem install bundler
    - bundle install
    - bundle exec jekyll build -d test
  stage: test
  artifacts:
    paths:
      - test

Run your pipeline

The cue.mod directory needs to be stored in your git repository, along with your pipeline.cue and .gitlab-ci.yml files. After recording them in a commit you can push your branch to GitLab and trigger the pipeline.

Whenever you update your CUE pipeline, re-run the cue export command shown above, and then use git to record any changes to these files and directories.